LoadXml (XmlDoc/XmlNode function)

Deserialize text string into XmlDoc Root or into Element XmlNode

LoadXml is a member of the XmlDoc and XmlNode classes.

This callable function converts a text string representation of an XML document into an empty XmlDoc, or of an XML fragment as one or more children of an Element XmlNode. This process is called deserialization, because the text representation of a document is called the serial form.

LoadXml returns a zero value if the deserialization is successful; it returns a non-zero value if deserialization is unsuccessful, the ErrRet option is used, and the particular error is tolerated.

Syntax

  [%pos =] nr:LoadXml(input, [options])

Syntax Terms

%pos

A %variable set to 0 if the deserialization is successful. If the ErrRet option is used, this %variable is set to the position within input at which an error is found.

nr

An expression that points to the XmlDoc or XmlNode to contain the deserialized representation of the XML document or fragment, respectively. If an XmlDoc, it must be EMPTY (see ?? refid=dstates.) prior to invoking LoadXml. If an XmlNode that is the root node of an XmlDoc, the XmlDoc must be EMPTY. Prior to Sirius Mods version 6.8, this method object had to be an XmlDoc; as of version 6.8, LoadXml is also available in the XmlNode class.

input

The text string, Longstring, or (as of Sirius Mods version 6.8) Stringlist to be deserialized. If a Stringlist, input consists of the concatenation of the Stringlist items with no insertion of line-end characters at the end of each item. If the nr method object is an XmlDoc or the root node of an XmlDoc, input must be valid as an entire XML document (for example, only one top-level element). If nr is a non-root XmlNode, input must be an XML fragment, that is, a substring of a serialized XML document, such that:

The fragment may contain undeclared prefixes. Any such prefixes must have declarations which are in effect at the Element node referred to by the method object of LoadXml; these declarations (along with that Element's default namespace) are inherited by the inserted fragment.
In all other respects, the fragment, if “wrapped” within a simple element start tag and end tag (such as <w> and </w>, respectively), is a legal XML document. The fragment can contain leading and/or trailing character content and/or multiple “top-level” elements; all of these become children of the method object XmlNode.

options

Any valid combination of the following terms:

AllowUntranslatable Allows all valid Unicode strings into the XML document. When this option is not specified, only Unicode strings that are not translatable to EBCDIC are disallowed. AllowUntranslatable allows untranslatable Unicode characters, but it does not affect untranslatable EBCDIC characters. As described in the ?? refid=ununic., it is recommended that you use AllowUntranslatable only if the application checks for translatability when accessing parts of the XmlDoc that may have untranslatable Unicode content. The AllowUntranslatable option is available as of version 7.6 of the Sirius Mods.
CrPreserve All whitespace characters in Element content are preserved, including carriage return. Unlike all other deserialization options, a carriage return in Element content does not undergo the normalization specified in the XML standard (and referred to in ?? refid=unlxml.). CrPreserve is mutually exclusive with the WspNewline, WspToken, and WspPreserve options, and with the LinefeedNoTrailingTabs option. The CrPreserve option was added in version 7.5 of the Sirius Mods, as well as implemented with a maintenance zap to the 7.4 Sirius Mods.
DTDIgnore If a “<!DOCTYPE&thinsp....>” clause is present in the document, it should be ignored. In any case, the DTD is not processed. If DTDIgnore is not present, the default behavior is to treat “<!DOCTYPE&thinsp....>” as a syntax error. DTD_Ignore is a synonym for DTDIgnore.
noteh
ErrRet Errors during deserialization are tolerated, the method object is not updated (retains its pre-call state), and the request continues. If ErrRet is not present, any error cancels the request. If ErrRet is present, some errors cancel the request and some are tolerated. Note: Errors tolerated when ErrRet is specified are explicitly noted in ?? refid=rclxml., with one exception: CCATEMP full conditions always cause a request cancellation.
LinefeedNoTrailingTabs For a Text node that consists of an initial line-end character and one or more tab characters, this option normalizes the content so the result is a single line-end character. The initial line-end (also called “newline”) character can be a linefeed character (LF) or a carriage-return (CR) by itself, or a carriage-return followed by a linefeed (CRLF), since (within Text nodes) all of these are normalized by the XML specification into a single line-end character. This option, added in Sirius Mods version 7.0, is compatible with, but takes precedence over, any of the other whitespace-handling options (WspNewline, WspToken, WspPreserve) except CrPreserve. See ?? refid=unwhite. for more information about this option and about whitespace handling.
ReplaceUnicode Converts Unicode characters using the replacements (if any) specified at your site by UNICODE updating commands that use the Rep subcommand (for example, UNICODE Table Standard Rep U=2122 '(TM)'). The replacement is performed on all names, element and attribute values, comments, and PI “values” in the document, after any entity and character references have been converted to characters. For further discussion and examples, see the ReplaceUnicode discussion in the “Usage Notes” ?? reftxt=* refid=unreplu.. For more information about the UNICODE command, see ?? refid=ucmd..
noteh.
WspNewline This option is designed to remove any whitespace inserted to make the structure of an XML document easier (for a person) to read. WspNewline removes the leading or trailing whitespace in the value of a Text node, if the whitespace sequence contains a newline (carriage return or linefeed) character. Note: This handling, the default whitespace option for this method, applies to the “physical value” of the representation of a Text node. In particular, markup such as a character reference (even of whitespace, for example,  ), a CDATA section, or any non-whitespace character delimits leading or trailing whitespace and is not affected. See ?? refid=unwhite. for more information.
WspToken Whitespace in Element content is normalized using the XPath normalize() function (leading and trailing whitespace removed, intermediate strings of whitespace replaced by a single blank character). WspToken is a good substitute for WspNewline to remove leading and trailing whitespace in cases where blanks (or tabs) and not line-end characters were used to make the document structure more readable — if it is tolerable to collapse intermediate whitespace sequences to single space characters. See ?? refid=unwhite. for more information.
WspPreserve All whitespace characters in Element content are preserved (after end-of-line normalization, as described in ?? refid=unwhite.). Wsp_Preserve is a synonym for WspPreserve.

Exceptions

This function can throw the following exception:

XmlParseError: If the method encounters a parsing error, properties of the exception object may indicate the location and type of problem. See ?? refid=xmlpars..

Usage Notes

As of Sirius Mods version 7.5, version="1.1" is accepted in the input to be deserialized. Formerly, only 1.0 was accepted.
None of the options terms may be specified twice.
The options terms may be specified in any case. For example, you can use WspPreserve and wsppreserve, interchangeably.
If the LoadXml method object is an XmlDoc or a root XmlNode, LoadXml will accept any of the input character sets specified below. The correspondence between these input character sets and the value of encoding in the XML declaration is explained in the description of the Encoding property of an XmlDoc, under its ?? refid=enctyp., and is also shown in the following two tables. In both tables below, all of the values of encoding in the XML declaration must be specified in all-uppercase letters, and n is a digit from 1 to 9 in the encoding value ISO-8859-n:

Input bytestream
XML declaration
ASCII codes below X'80'
UTF-8, ISO-8859-n, or none
ASCII codes up to X'FF'
ISO-8859-n
UTF-8 (with characters above X'7F')
UTF-8 or none
UTF-16
UTF-16 or none
EBCDIC
UTF-8, ISO-8859-n, or none
Unicode (User Language)
UTF-8, ISO-8859-n, or none

XML declaration
Input bytestream
UTF-8
UTF-8 (which includes ASCII codes below X'80'), EBCDIC, or Unicode
UTF-16
UTF-16 (including a two byte order mark bytes as a preamble to the XML document input stream)
ISO-8859-n
ASCII codes up to X'FF', EBCDIC, or Unicode
none
UTF-8, UTF-16, ASCII, EBCDIC, or Unicode

In certain LoadXml error cases (for example, an input containing an ASCII code above X'7F' without an XML declaration containing ISO-8859-n), a group of error messages is issued to display:
- A line that contains the erroneous string as received
- A line with an ASCII-to-EBCDIC translation of the string
- Additional lines that display the input byte halves in base 16
For example, the following messages are output after an 8-bit ASCII input fails because no accompanying ISO-8859-n encoding was specified:
```
     MSIR.0668: XML doc parse error: invalid first byte of
                UTF-8 encoding near or before position 14
    MSIR.0708: C: ????????????????
    MSIR.0708: E: copyright(?)</A> (ASCII to EBCDIC)
    MSIR.0708: X: 6677766672A23243
    MSIR.0708: X: 3F0929784899CF1E
    MSIR.0665:              |
```
If the LoadXml method object is a non-root XmlNode, LoadXml accepts a Unicode string or a bytestream it treats as EBCDIC.
As described in ?? refid=u80., serializing with LoadXml may require translation of the input document using the Unicode tables. This depends on the version of the Sirius Mods (that is, whether XmlDocs are maintained in EBCDIC or Unicode) and on which of the input character sets described above is used.
An XML fragment does not provide for inserting an Attribute into an Element node. For example, the following does not achieve it:
```
    %d Object XmlDoc Auto New
    %n Object XmlNode
    %n = %d:AddElement('top')
    %n:LoadXml('foo="bar"')
    %d:Print
```
The input to LoadXml above is simply stored as the character content of the Element containing the fragment, so the result is:
```
    <top>foo="bar"</top>
```
To add the Attribute foo with the value “bar”, replace LoadXml in the example above with the AddAttribute method (??AddAttribute).
If the method object refers to the Root node of an XmlDoc, the LoadXml method in the XmlNode class behaves exactly as the LoadXml method in the XmlDoc class. For example:
```
    %d Object XmlDoc Auto New
    %n Object XmlNode
    %n = %d:SelectSingleNode
    %n:LoadXml('<?xml version="1.0"?><top><inner/></top>')
```
When the Root node is the method object, the serialized input must be a legal XML document (for example, the XmlDoc must be Empty, and the serialized input must contain exactly one top-level element).
Whitespace handling
- The “Wsp” whitespace-handling options (WspPreserve, WspNewline, and WspToken) and the CrPreserve whitespace option are mutually exclusive; if none of them is specified, WspNewline is in effect. Although the LinefeedNoTrailingTabs option is also concerned with whitespace, it is distinct from, yet compatible with, any of the three “Wsp” options, but it is not compatible with the CrPreserve option.
- Except for CrPreserve, the whitespace-handling options are applied after the XML standard whitespace conversions that Janus SOAP applies in all other cases. As described in ?? refid=nornl., the standard specifies that all carriage return/linefeed sequences and carriage return sequences are to be converted to linefeeds when deserializing. Using the CrPreserve option bypasses this rule.
- The whitespace-handling options do no whitespace conversion (beyond the XML standard conversions) on Element content that is “protected” by the xml:space="preserve" attribute. “Protected” by the xml:space="preserve" attribute means an element E that either:
  - has the xml:space attribute with the value preserve
  - is contained in an element A with that attribute and value, and there is no element that is a descendent of A and an ancestor of E with the xml:space attribute with the value default
  Elements that are not protected by the xml:space="preserve" attribute have whitespace handled according to the option in effect for the deserialization.
- There is no whitespace normalization comparable to the LoadXml whitespace-handling options for the Add and Insert...Before functions that create a Text node (??AddElement, ??InsertElementBefore, ??AddText, and ??InsertTextBefore).
- Whitespace normalization applies to the characters in the input serialized string, not to the values after entity substitution. In ?? refid=exload., see the fourth example (which contains 	).
- If input is a Stringlist, LoadXml inserts a linefeed character after each item in the Stringlist as part of concatenation prior to deserialization. The linefeed is then subject to the method's whitespace handling options, so it is usually removed (as leading or trailing whitespace).
- Using WspNewline or WspToken reduces the space consumed by individual Text nodes, and in some cases collapses all whitespace content between markup to the null string, so it is not stored as a Text node. This reduces the storage required by the XmlDoc, speeds up XPath and node access processing, and makes the output of, say, the Print subroutine easier to read.
- The LinefeedNoTrailingTabs option only affects Text nodes that contain an initial line-end character followed by any number of tabs and nothing else. The LinefeedNoTrailingTabs effect on such a Text node, whether it is specified with or without any of the “Wsp” options, is to store the value of the node as a single line-end character. One example of the use of the LinefeedNoTrailingTabs option is an input XML document to be deserialized for which both of the following are true:
  - A digital signature is needed of a subtree in the document.
  - The input subtree contains a linefeed and one or more tabs that separate markup, and the linefeed must be kept but the tabs discarded for the signature.
  For information about exclusive canonicalization, serialization expressly designed for digital signatures, see Serial.
Deserializing Unicode strings
- The LoadXml AllowUntranslatable option lets you deserialize Unicode strings that contain characters that are not translatable to EBCDIC. For example, LoadXml accepts the Unicode trademark character (U+2122) only if you specify allowUntranslatable, as in the following. The U function below is described ?? refid=umeth..
```
    %u is unicode Initial('&#x2122;':U)
    %nod:LoadXml(%u, 'allowUntranslatable')
```
  If you remove allowUntranslatable, this LoadXml statement fails, because the Unicode trademark character does not translate to an EBCDIC character. By default, the method detects any untranslatable characters in the serialized input XML document; it also throws an XmlParseError exception (?? refid=xmlpars.) with reason UntranslatableUnicode (unless the ErrRet option is specified).
  This default detection of non-translatable characters may suit your purposes. That is, it ensures that subsequent access to the deserialized content is performed without any Unicode to EBCDIC translation errors. For example:
```
    %doc:LoadXml
     ...
    %val Longstring
    %val = %doc:Value(%xpath)
```
  Although the Value method returns a Unicode string, the assignment to the EBCDIC string %val will not fail due to a Unicode translation problem: if there is any untranslatable Unicode (including, of course, strings in the XML document which your application never accesses), the LoadXml operation fails.
  If you use AllowUntranslatable, all Unicode characters in a serialized input XML document are allowed and stored in the XmlDoc. Your stored data may contain content that is not translatable to EBCDIC, however. A subsequent attempt to access such content that performs Unicode to EBCDIC translation (like the Value method statement above) might cause request cancellation.
  You should therefore use AllowUntranslatable only if there is also a check for translatability when parts of the XmlDoc that may have non-translatable Unicode content are accessed. The code below, for example, shows a way to get the benefit of specifying AllowUntranslatable while limiting the risk of request cancellation.
  In the following example, it is believed that only the element comments might contain untranslatable Unicode among all the data accessed from the XML document:
```
    %resp:LoadXml(%doc, 'AllowUntranslatable')
     ...
    %uVal Unicode
    %val Longstring

    %uVal = %node:Value('comments')
    Try %val = %uVal:UnicodeToEbcdic
    Catch CharacterTranslationException
      %val = %uVal:UnicodeToEbcdic(CharacterEncode=True)
      Print 'Untranslatable Unicode, character encoded:' -
         And %val
    End Try
```
  Note: Unicode values, untranslatable or not, are always allowed when they are added to an XmlDoc using one of the Add or Insert methods which “directly store” into an XmlDoc. For example, the following fragment adds an Element node with a value that is the Unicode trademark sign:
```
    %node:AddElement('notation', '&#x2122;':U)
```
  Note: LoadXml accepts input that contains XML hex character references but not input that contains XHTML entity references (other than the five predefined entities described in ?? refid=entrefs.). For example, this statement successfully loads a copyright character:
```
    %d:LoadXml('<a>&#xA9;</a>')
```
  And this statement successfully loads a greater-than sign:
```
    %d:LoadXml('<a>&gt;</a>')
```
  But this statement with a copyright character entity fails:
```
    %d:LoadXml('<a>&copy;</a>')
```
  You can load a copyright character, however, if you decode the reference and convert to Unicode before the deserialization. For example:
```
    %d:LoadXml('<a>&copy;</a>':U)
```
  For more information about working with Unicode characters, see Strings and Unicode.
- The ReplaceUnicode option lets you replace certain Unicode input characters with those characters you have explicitly specified (by UNICODE commands in your site's Model 204 CCAIN stream). For example, assume the following command is in CCAIN:
```
    UNICODE Table Standard Rep U=2122 '(tm)'
```
  Given the above command, the ReplaceUnicode option for LoadXml is shown in the following fragment (the UnicodeWith method is described ?? reftxt=* refid=uniwith., and Utf16ToUnicode ?? reftxt=* refid=fu162u.):
```
    %u Unicode Initial('<a>')
    %u = %u:UnicodeWith('2122':X:Utf16ToUnicode)
    %u = %u:UnicodeWith('</a>':U)
    %d:LoadXml(%u, 'ReplaceUnicode')
    %d:Print
```
  The result is:
```
    <a>(tm)</a>
```
  In the preceeding example, the stream of input characters to LoadXml contains the Unicode character U+2122. Since the ReplaceUnicode option applies to both the stream of input characters and to the character value of character references, consider the following fragment (assuming the same CCAIN line as above):
```
    %d:LoadXml('<a>&#x2122;</a>', 'ReplaceUnicode')
```
  The result is also:
```
    <a>(tm)</a>
```
  In this case, U+2122 does not occur in the input character stream, but it is the value of the character reference.
  Notes:
  - It is an error to be processing a replacement string within a character reference. For example, assume the following two lines are in CCAIN:
```
    UNICODE Table Standard Rep U=00B2 '2'
```
    Given the above command, the following fragment gets a parse error, because the replacement string is being used as part of a character reference:
```
    %d:LoadXml('<a>&#x' With '&#xB2;':U With ';</a>', -
       'ReplaceUnicode')
```
    As a consequence of this rule, a replacement string should not contain an ampersand character (assuming that the ReplaceUnicode option will be used).
  - Replacement of a Unicode character due to the ReplaceUnicode option is only done while processing names and values in the XML document. It is an error if the end of the name or value occurs and the replacement string has not been exhausted. In other words (again assuming that the ReplaceUnicode option will be used), a replacement string should not have “XML markup” that might end a string, such as a quotation mark or a left angle bracket (<). For example, assume the following line is in CCAIN:
```
    UNICODE Table Standard Rep U=2122 '(trademark)<tm>'
```
    Given the above command, the following fragment gets a parsing error, because the '<' that is encountered in the replacement string ends the element content:
```
    %d:LoadXml('<a>&#x2122;</a>':U, 'ReplaceUnicode')
```
  - If a parsing error occurs after processing a Unicode character that has been replaced, the error display of the input stream will contain the replacement string, and the replaced character will not be displayed. However, if the character being replaced was introduced as a character reference, the character reference remains in the display of the input stream.

Examples

The following code creates the XmlDoc representation of the indicated XML document:

    %d Object XmlDoc
    %d = New
    %d:LoadXml('<zen>The Buddha dog says</zen>')

The following code creates an XML document as plain text for a test (or for some other application):

    %d Object XmlDoc
    %d = New
    %sl Object Stringlist
    %sl = New
    Text to %sl
       <test>
          <test2>
             supercalifragilisticexpailodocious
          </test2>
       </test>
    End Text
    %d:LoadXml(%sl)

The following code calls a subroutine which uses the ErrRet option:

    %d Object XmlDoc
    %d = New
    %s Longstring
     ... setup the (serialized) document in %S
    %d = New
    Call IntoXML(%d, %s)
     ... do interesting things with the XmlDoc
     ... setup another document in %S
    Call IntoXML(%d, %s)
     ...
    Subroutine IntoXML(%d Object XmlDoc, %S Longstring)
    If %d:LoadXml(%S, 'ErrRet') Then
       ... error handling code ...
    End If
    End Subroutine

As stated for the options argument in the LoadXml syntax, whitespace normalization applies to the characters in the input serialized string, not the values after entity substitution. Therefore the values of elements “foo1” and “foo2” created by the following two LoadXml invocations are different:
```
    %t = $X2C('05')

    %d:LoadXml('<foo1>' With %t With %t With '</foo1>',   -
                 'wsptoken')

    %d2:LoadXml('<foo2>&#x09;&#x09;' With '</foo2>',      -
                 'wsptoken')
```
In the following fragment, element a, which contains leading and intermediate whitespace, is deserialized with the WspToken option, then printed:
```
     ...
    %d  Object XmlDoc auto new
    %le string len 16
    %le = $X2C('0D25')
    %d:LoadXml('<a foo="   bar   "  >   x' With %le      -
                 With 'y</a>', 'WspToken')
    Print %d:Serial('.', 'EBCDIC')
     ...
```
The result shows that WspToken removes the leading whitespace — in the Element content, not in the Attribute value — and replaces the intermediate linefeed (the initial carriage return removed as the XML standard normalization dictates) with a single blank:
```
    <a foo="   bar   ">x y</a>
```
If WspNewline is used instead, the leading whitespace remains (it contains no line-end characters), and the intermediate linefeed (represented below by a question mark) also remains (it is not leading or trailing):
```
    <a foo="   bar   ">   x?y</a>
```
In this example, using the WspPreserve option gives the same result as WspNewline: no whitespace is removed, except for the initial carriage return due to the XML standard normalization.
If the example is changed slightly so the Text node includes only tab characters and a leading line-end character, and LinefeedNoTrailingTabs is specified:
```
     ...
    %le = $X2C('0D25')
    %tb = $X2C('05')
    %d:LoadXml('<a foo="   bar   "  >' With %le With %tb  -
               With %tb With '</a>', 'LinefeedNoTrailingTabs')
    Print %d:Serial('.', 'EBCDIC')
     ...
```
The resulting Text node contains only the line-end character:
```
    <a foo=" bar ">?</a>
```
The Janus SocketsR documents the HttpResponse object, whose ParseXml method has the same options as LoadXml. The following fragment requests, receives, and deserializes an XML document from a Web server:
```
    %httpreq object HttpRequest
    %httpresp object HttpResponse
    %doc object XmlDoc
    %httpreq = New
    %doc = New
    %httpreq:URL = 'foo.com/bar'

    %httpresp = %httpreq:Get('HTTP_CLIENT')

    If %httpresp:ParseXML(%doc, 'ErrRet') Then
      ... invalid document received from Web server
    End If
```
Note: If you use $Sock_Recv and LoadXml directly instead of using an HTTP Helper object, always use the BINARY option of $Sock_Recv, so that LoadXml can recognize the character encoding inherent in the serialized XML document.

Request-Cancellation Errors

Method object doc is not EMPTY.
Option is invalid.
Insufficient free space exists in CCATEMP.
A syntax error occurred in the representation of the XML document in input (this is tolerated if the ErrRet option is specified).