FindNextItem (GenericNamedArraylist function)

Next item that matches some selection criteria (FloatNamedArraylist, NamedArraylist, and UnicodeNamedArraylist classes)

This function searches "forward" in the NamedArraylist to find and return the next item that matches a specified criterion. The criterion is supplied by the SelectionCriterion object that is a required FindNextItem parameter. If no item satisfies the criterion, the request is cancelled and an ItemNotFound exception (?? refid=itemnfe.) is thrown.

FindNextItem is available in Sirius Mods version 7.6 and later.

Syntax

%item = anyNal:FindNextItem( selectionCriterion, [Start= number]) Throws ItemNotFound

Syntax terms

%item

A variable of the type of the items in the NamedArraylist to contain the item that is located by the search.

%namrayl

A NamedArraylist object.

criterion

A SelectionCriterion object, which is a relational expression that is applied to a %namrayl item value to determine whether the value satisfies the expression. The expression consists of a function, an operator, and a numeric or string value. For example, GT(this, -11) is the criterion this > -11, where this is an identity function that simply returns the item's value. The first item tested by FindNextItem that satisfies this expression is the method's return value. The function in the criterion is a method value (a method or class member name literal, or a method variable) for a method that operates on items of the type specified on the %namrayl declaration and that returns a numeric or string value. This is described further in "Specifying a SelectionCriterion's parameters".

Start= itemnum

The number of the item after which to begin the search. If the itemnum value of Start is 2, item 3 is the first item considered. The value of Start may be 0 through the number of items in the NamedArraylist. For a NamedArraylist of three items, itemnum may be 0, 1, 2, or 3. This is an optional argument, and it defaults to 0. If you specify a value, the parameter name Start is required.

Usage notes

• If the value of Start is greater than the number of items in the NamedArraylist, the request is cancelled. If the value of Start is equal to the number of items, the request is cancelled, but an ItemNotFound exception is thrown.
• The FindPreviousItem function is identical to FindNextItem except that it searches backward in the NamedArraylist.

Examples

The following request contains two FindNextItem calls and one FindPreviousItem call, each with a class Variable as the function in the SelectionCriterion:

    Begin
    class staff
      public
        variable name is string len 20
        variable status is string len 8
        constructor newf(%a is string len 10, -
          %b string len 8)
        function myprint is longstring
      end public

      constructor newf(%a is string len 10, -
        %b string len 8)
        %this:name = %a
        %this:status = %b
      end constructor

      function myprint is longstring
        return %this:name with ' ' with %this:status
       end function
     end class

     %stf is object staff
     %old is namedArraylist of object staff
     %old = new
     %old('Jim') = newf('Red', 'employed')
     %old('Jed') = newf('Black', 'retired')
     %old('Jan') = newf('Green', 'employed')
     %old('Jud') = newf('Brown', 'retired')
     %old('Jon') = newf('White', 'tired')

     %stf = %old:findNextItem(Eq(status, 'employed'))
     print %stf:myprint

     %stf = %old:findNextItem(Gt(name, 'Starks'))
     print %stf:myprint

     %stf = %old:findPreviousItem(AND(Lt(name, 'Starks'), -
                                  Eq(status, 'employed')))
     print %stf:myprint

    End

The result is:

    Green employed
    White tired
    Red employed

See also

Arraylist class FloatNamedArraylist class NamedArraylist class UnicodeNamedArraylist class	List of Arraylist methods List of FloatNamedArraylist methods List of NamedArraylist methods List of UnicodeNamedArraylist methods List of Collection methods	Arraylist methods syntax FloatNamedArraylist methods syntax NamedArraylist methods syntax UnicodeNamedArraylist methods syntax
Notation conventions for methods